hk-lisse

Fourier Transform for Traders, by John Ehlers.

Dans le numéro de janvier 2007 de S&C, on retrouve un dernier article de John Ehlers sur la façon d'utiliser les cycles pour le trading.  Il propose d'utiliser la "Discrete Fourier Transform" (DFT) pour le tuning des indicateurs.  Il prend en exemple un RSI où la période est fonction du cycle dominant calculé par la DFT.  Je ne suis pas un fan du RSI, j'ai rentré la période adaptative dans un système de moyennes mobiles (exemple proposé par le développeur de WEALTH-LAB).  Les signaux sont donnés par le croisement de la courbe de régression linéaire (de période = 1/4 cycle) avec la moyenne mobile simple (de période = 1/2 cycle).  Voici une vue de KO avec les 2 moyennes et dans la fenêtre du bas, l'indicateur qui retourne le cycle dominant.

Plusieurs remarques :

 - Je ne suis pas certain de l'exactitude des calculs, après une rapide comparaison avec le graphe d'IBM présenté dans l'article.  J'éditerai le programme au besoin (vous pouvez toujours laisser un commentaire dans la file dédiée si vous trouvez un bug).

 - Le logiciel Prorealtime montre une nouvelle fois toutes ses limites avec l'impossibilité d'inclure des boucles dans des boucles.........  Message de boucle sans fin !  Après avoir planché pendant plus d'une semaine, je vous donne le résultat même si comme je l'ai signalé plus haut, je ne suis pas sûr de celui-ci.

 - Le programme rame, il faut près de 40 minutes pour afficher un graphe de 150 barres !  Il est donc inexploitable dans sa forme actuelle, j'imagine le temps nécessaire pour un screener ou un backtest !

 - Prochaines étapes : essayer de rendre le programme plus rapide et le comparer avec la méthode proposée par Dennis Meyers (Mesa Vs Goertzel DFT).

Voici le code pour Prorealtime de l'indicateur de cycle dominant :

maxpwr = CALL "sousprog dft"[8]
for kk=9 to 50
    mys=call "sousprog dft"[kk]
    if mys>maxpwr then
        maxpwr=mys
    endif
next
if barindex <60 then
    maxpwr=undefined
endif
num=0
denom=0
for kk=8 to 50
    mys=call"sousprog dft"[kk]
    db=-10*log(0.01/(1-0.99*mys/maxpwr))/log(10)
    if db>20 then
        db=20
    endif
    if db<3 then
        thre=3-db
        num=num+kk*thre
        denom=denom+thre
    endif
next
if barindex>60 then
    cyc=num/denom
else
    cyc=undefined
endif

return cyc

Ainsi que le code du sous-programme utilisé pour contourner les faiblesses du logiciel, il faut introduire la période en variable (peri) :

pr=medianprice
if barindex<=5 then
    hp=pr
    cl=pr
else
    per=360/40
    cosper=cos(per)
    alph=(1-sin(per))/cosper
    hp=0.5*(1+alph)*(pr-pr[1])+alph*hp[1]
    cl=(hp+2*hp[1]+3*hp[2]+3*hp[3]+2*hp[4]+hp[5])/12
endif
cospart=0
sinpart=0
for n=0 to 49
    cycper=(360*n)/peri
    cospart=cospart+cl[n]*cos(cycper)
    sinpart=sinpart+cl[n]*sin(cycper)
next
pwr=square(cospart)+square(sinpart)

return pwr

Using Fisher Transform by John Ehlers.

Dans le numéro de novembre 2002 de S&C, il y a un article de Ehlers sur la transformation de Fisher.  Une copie en pdf se trouve ici, pour les explications.  Voici une vue de l'indicateur appliqué à la Société Générale (j'essaye de coller à l'actualité !).

Et le code pour Prorealtime :

p=MedianPrice
len=10
maxh=highest[len](p)
minl=lowest[len](p)
if barindex<len then
    val1=2*((p-minl)/(maxh-minl)-0.5)
else
    val1=0.33*2*((p-minl)/(maxh-minl)-0.5)+0.67*val1[1]
endif
if val1>.99 then
    val2=.999
elsif val1<-0.99 then
    val2=-0.999
else
    val2=val1
endif
if barindex<len then
    fish=log((1+val2)/(1-val2))
else
    fish=0.5*log((1+val2)/(1-val2))+0.5*fish[1]
endif

return fish,fish[1],0

Cycles : le point sur les enveloppes.

Comme je vois que certains sont impatients de lire la suite des articles consacrés aux cycles, je vous poste ce petit compte rendu qui vous montre où j'en suis.  Voici le graphe d'INTC.

Pour l'instant, j'arrive à tracer les enveloppes qui sont décrites par Hurst et Millard.  J'ai encore quelques problèmes d'ajustements : en A, B,  et C, la courbe inférieure long terme devrait se décaler vers le haut, par contre en D, c'est la courbe supérieure qui est trop basse.  Les courbes sont tracées par tâtonnement, j'essaye d'automatiser la longueur et la largeur de celles-ci.

Si l'analyse des cycles est correcte, on devrait avoir un rebond d'INTC vers le haut du canal mauve.  N'oubliez toujours pas que les courbes sont tracées avec les données futures connues et qu'elles changent !

Over / Under Divergence.

Sur le site de NQoos, il y a un setup de divergence sur Stochastics  :  "Over / Under Divergence by Birdman".  Toutes les informations nécessaires se trouvent sur la page, je vous déconseille d'aller sur Intellitraders.com, car l'anti-virus me donne une alerte.

Les conditions telles que je les ai codées sont :

 - Une divergence classique haussière sur le Stochastic 7,3.  La divergence est validée sur un simple zigzag du Stochastic.

 - Le premier creux du Stochastic 7,3 est inférieur au Stochastic 21,10 et le second supérieur.

 - La bougie précédant le signal doit marquer un plus bas de 7 barres.

 - La bougie du signal doit avoir un plus haut supérieur à celui de la barre précédente et Close>Open.

Il serait pertinent AMHA de backtester l'efficience de certaines conditions :

 - Nécessicité d'avoir une bougie verte.

 - Avoir le Stochastic 21,10 orienté à la hausse.

 - Valider la divergence non pas avec un zigzag mais avec le croisement de %K et %D.

 - Avoir le point bas sur la bougie[2] ou [0] et non pas la bougie[1].

Voici un exemple de signal :

Il y a peu de signaux, c'est pour cela que je m'interroge sur l'utilité de toutes les conditions.

Il faut bien lire les 4 remarques à la fin de la page de NQoos, particulièrement celle sur le "Strong Trend".  Pour le higher timeframe, 5 ou 6 fois l'unité de temps devrait être correct.  Dans ce cas, il est intéressant de chercher sur celui-ci des figures telles que "Mof" ou "Slingshot" (voir Buffy sur Google, pour ceux qui ne connaissent pas encore).  Il faudrait regarder aussi  du côté du range de la bougie de manière à avoir un R/R jouable.

Voici le code pour Prorealtime de la version "achat", avec les conditions de base.  Je vous laisse faire la version "vente".

x=Stochastic[7,3](close)
z=stochastic[21,10](close)
if x<x[1] then
    lo=min(lo,x)
    lowco=min(lowco,min(low,low[1]))
endif
if x>x[1] and x[1]<x[2]  then
    zt1=zt
    zt=z[1]
    sto2=sto1
    sto1=lo
    lo=100
    p3=p1
    p2=min(p1,lowco1)
    p1=min(lowest[3](low),lowco)
    if p2=p1 then
        p2=min(p3,p4)
    endif
    lowco=100000
    lowco1=100000
endif
if x>x[1] then
    p4=lowco1
    lowco1=min(lowco1,low)
endif
c1=( p1<p2 and sto1 > sto2 and x>x[1] and x[1]<x[2])
c2=(c1 and sto2<zt1 and sto1>zt )
if c2 and low[1]=lowest[7](low) and high>high[1] and close>open then
    divi=3
else
    divi=0
endif
return divi

Comment tester une stratégie sur un ensemble de valeurs ?

Une des lacunes du logiciel Prorealtime est de ne pas pouvoir tester les stratégies de trading sur un portefeuille d'actions.  Il faut à chaque fois relancer le backtest en changeant le support pour ainsi appliquer le système de trading aux titres un par un.  Avec une stratégie simple, je vais montrer comment on peut améliorer la chose.

La stratégie : achat lors du croisement A+ (de type fort) de la moyenne 7 simple avec la moyenne mobile 20 simple.  On prend position à la cloture de la barre si celle-ci est inférieure à 75% de la Bollinger Bandwdth et le high < à 85%, l'objectif est la Bollinger supérieure et le stop une cloture sous la moyenne 20 simple.  Cette stratégie sert juste d'exemple, rien ne dit qu'elle est gagnante, attention !

Le code :

REM Achat

indic1 = Average[7](close)
c1 = (indic1>indic1[1] and indic1[1]>indic1[2])
indic2=std[20](close)
indic3 = Average[20](close)
c2 = (indic3>indic3[1] and indic3[1]>indic3[2])
c10=(indic1 crosses over indic3)
indic5 = indic3+indic2
c3 = (close <= indic5 and close > indic3)
indic6 = BollingerUp[20](close)
c4 = (high <= ((indic6-indic5)*0.4)+indic5)
c11=(close>open)
IF c1 AND c2 AND c3 AND c4 and c10 and c11 THEN
    BUY 20000 CASH AT MARKET THISBARONCLOSE
ENDIF

REM Vente
sell at indic6 limit
c5 = (close<indic3)
IF c5 THEN
    SELL  AT MARKET THISBARONCLOSE
ENDIF

Une vue d'un trade sur  DELL, M7 haussière (en jaune), M20 haussière (en blanc), close<75% bbw (en ciel)  :

L'astuce consiste à construire un indicateur qui fera office de backtest.  Voici le code de l'indicateur pour le backtest pris en exemple, on voit bien que les 2 courbes sont identiques.

REM Achat
once cap=100000
indic1 = Average[7](close)
c1 = (indic1>indic1[1] and indic1[1]>indic1[2])
indic2=std[20](close)
indic3 = Average[20](close)
c2 = (indic3>indic3[1] and indic3[1]>indic3[2])
c10=(indic1 crosses over indic3)
indic5 = indic3+indic2
c3 = (close <= indic5 and close > indic3)
indic6 = BollingerUp[20](close)
c4 = (high <= ((indic6-indic5)*0.4)+indic5)
c11=(close>open)
IF c1 AND c2 AND c3 AND c4 and c10 and c11 THEN
    nbr=round (20000/close)
    cap=cap-(nbr*close)-5
    flag=1
ENDIF

REM Vente
if high>=indic6[1] and flag=1 then
    flag=0
    cap=cap+(nbr*indic6[1])-5
endif
IF close<indic3 and flag=1 tHEN
    flag=0
    cap=cap+(nbr*close)-5
endif
if flag=1 then
    capital=cap+(nbr*close)
else
    capital=cap
endif
return capital

Maintenant, je peux appliquer cet indicateur (comme critère) sur un screener.  De nouveau, on se retrouve confronté aux limites du logiciel : seules 30 valeurs sont affichées (je dois donc procéder en plusieures fois), le screener étant limité aux  254 derniéres barres, les résultats du backtest concernent ce même intervalle de temps.

Une vue du screener (on retrouve bien les données pour DELL, en 15ième position) :

Une derniére astuce : si je souhaite connaître les signaux pour une certaine période comprise dans les 254 dernières barres, on peut faire un tri avec une boucle.  Ici, un exemple sur les 10 dernières barres (toujours avec la même stratégie) :

REM exemple de screener avec boucle
for i=0 to 9
    indic1 = Average[7](close)
    c1 = (indic1>indic1[1] and indic1[1]>indic1[2])
    indic2=std[20](close)
    indic3 = Average[20](close)
    c2 = (indic3>indic3[1] and indic3[1]>indic3[2])
    c10=(indic1 crosses over indic3)
    indic5 = indic3+indic2
    c3 = (close <= indic5 and close > indic3)
    indic6 = BollingerUp[20](close)
    c4 = (high <= ((indic6-indic5)*0.4)+indic5)
    c11=(close>open)
    IF c1 AND c2 AND c3 AND c4 and c10 and c11 THEN
        flag=1
    else
        flag=0
    ENDIF
         
    c15=(flag=1)
    criteria = volume
    c2=(volume>1000000)
    SCREENER[c15[i] and c2[i]] (criteria AS "volumei")
next

L'écran me retourne les valeurs avec un signal sur les 10 dernières barres (ça dure assez longtemps mais ça marche).  On voit que pour cette stratégie, il y en a eu très peu. 

Hidden Divergence sur le Nasdaq Composite.

Voici un exemple de divergence cachée, cela signifierait la poursuite de la baisse.

Et pour le même prix, une ETE qui se profile en UT week !

Gestion des positions pour la séance du 11 décembre.

Je suis finalement sorti de TDG au B/E, tant pis si on est plus haut.   J'ai quitté DKS également.  Je suis flat pour attendre la Fed et la volatilité.

Divergences : un cas concret, deuxième partie.

Première étape : le programme de divergence sur le stochastic.

------------------------------------------------------------------------------

J'ai un programme simple de détection des divergences haussières sur le stochastic.  Voici le problème que j'ai à résoudre :

Normalement, le point bas sur les cours se fait alors que le stochastic est sous son signal.  Mais parfois, il se fait alors que le stochastic a déjà croisé à la hausse (exemple 3 et 1).  Il peut se faire également juste avant que le stochastic ne croise son signal à la baisse (exemple 2).

Je vous donne pour info, le programme actuel, pour vous montrer le cheminement (je dois maintenant l'améliorer pour tenir compte du problème rencontré) :

x=Stochastic[14,3](close)
y=average[5](x)
if x<y then
    lo=min(lo,x)
    lowco=min(lowco,low)
endif
if x CROSSES OVER y  then
    sto2=sto1
    sto1=lo
    lo=100
    p2=p1
    p1=lowco
    lowco=100000
else
endif
if p1<p2 and sto1 > sto2 and x crosses over y and x>x[1]  then
    sign=10
else
    sign=0
endif
return sign

Edit 9/12 à 19h23 :

Bon voici à quoi j'arrive sur le programme stochastic, si je trouve des anomalies, je modifierais........

x=Stochastic[14,3](close)
y=average[5](x)
if x<y then
    lo=min(lo,x)
    lowco=min(lowco,min(low,low[1]))
endif
if x CROSSES OVER y  then
    sto2=sto1
    sto1=lo
    lo=100
    p3=p1
    p2=min(p1,lowco1)
    p1=min(lowest[3](low),lowco)
    if p2=p1 then
        p2=min(p3,p4)
    endif
    lowco=100000
    lowco1=100000
endif
if x>y then
    p4=lowco1
    lowco1=min(lowco1,low)
endif

if p1<p2 and sto1 > sto2 and x crosses over y and x>x[1]  then
    sign=10
else
    sign=0
endif
return sign

Je prends en compte le low juste avant le croisement à la baisse (exemple 2),   le low de la bougie du croisement à la hausse (exemple 1), et le low après le croisement à la hausse si celui-ci n'est pas égale au low avant le croisement à la baisse.  (j'espère que vous suivez ?)

On peut filtrer l'alerte de divergence en testant la différence entre le stochastic de la barre actuelle et celui de la barre précedente (pour l'instant, je teste seulement x>x[1]).  On peut aussi exiger que le signal du stochastic soit à la hausse (croisement a+ ?) ou encore regarder le R/R avec la position par rapport aux bandes de Bollinger ou bien enfin tester le high de la bougie d'alerte.  Tout ça à mettre en place lors du backtest.........

Seconde étape : le programme de divergence potentielle sur le MACD.

--------------------------------------------------------------------------------------

 Voici le premier jet du programme de détection de divergences potentielles, le cours marque un plus bas et non le MACD.  Le code retourne également les divergences validées :

m=MACDline[9,19,6](close)
s=exponentialaverage[6](m)
if m<s then
    lo1=min(lo1,m)
    lowco=min(lowco,low)
endif
if m>s then
    lowco1=min(lowco1,low)
endif
if m CROSSES OVER s  then
    a=lo1
    lo1=100
    c=min(lowco,lowco1)
    lowco=100000
    lowco1=100000
    a1=a0
    a0=a
    c1=c0
    c0=c
endif
if m crosses over s and a0>a1 and c0<c1 then
    sign=1
else
    sign=0
endif
minmac=lowest[4](m)
minco=lowest[5](low)
if m<s and minco<c0 and minmac>a0 then
    pre=.5
else
    pre=0
endif

return sign,pre

Avec une vue de l'indicateur, l'historigramme noir retourne la divergence possible et la barre blanche signale la validation de la divergence (le MACD croise son signal) :

-----------------------------------------------------------

Il vous suffit de combiner les 2 programmes : (divergence potentielle MACD or divergence validée MACD) and divergence stochastic.  Voici des exemples d'applications : en 1 un faux signal, en 2 la divergence stochastic est simultanée avec celle du MACD, et en 3 et 4, la divergence stochastic précède celle du MACD.

A première vue, il y a peu de reversalday.  Je ferai néanmoins un article sur le sujet.  N'oubliez pas qu'il existe une file commentaires ici, j'attends vos remarques.

Backtest : existe-t-il une corrélation entre les bougies semaines et jours ?

La question a été posée sur le site, par exemple : pour une semaine positive, quelle chance (?) d'avoir un lundi positif également ?

Voici une vue du CAC avec l'indicateur, l'historigramme indique la corrélation.  Sur 309 semaines, on a un taux de 45,614% après une semaine rouge et un taux de 46,377% après une semaine verte.

Et le code de l'indicateur pour Prorealtime :

once ouv=open
dw=DayOfWeek
if dw<dw[1] then
    ouv1=ouv
    ouv=open
    clot=close[1]
    flag=1
else
    flag=0
endif
if clot>ouv1 and flag=1 then
    sem=1
    cc=cc+1
else
    if clot<ouv1 and flag=1 then
        sem=-1
        hh=hh+1
    else
        sem=0
    endif
endif
if flag=1 then
    cor=sem
else
    cor=0
endif
if cor=1 and close>open then
    aa=10
    bb=bb+1
endif
if cor=-1and close<open then
    aa=-10
    gg=gg+1
endif
if cor=0 then
    aa=0
endif

return  aa,(bb/cc)*100,(gg/hh)*100

Edit 8/12, 17h00 : afin de comparer avec les données de chrism, voici les résultats du test avec Prorealtime :

Le test est fait sur la première barre qui suit la semaine (donc le mardi, par exemple si le lundi est férié). 

Depuis le 1/1/1988 : semaine haussière => 1er jour vert à 50,439%,  semaine baissière => 1er jour vert à 55.414%.

Depuis le 1/1/2000 : semaine haussière => 1er jour vert à 46.606%,  semaine baissière => 1er jour vert à 55,959%.

Depuis le 1/1/2002 : semaine haussière => 1er jour vert à 46.377%,  semaine baissière => 1er jour vert à 54.386%. (résultats déjà donnés)

Hier, je suis rentré sur GRMN et puis j'ai été sorti au B/E lors de la descente.  Sur PLL, trade réussi même si je suis rentré un peu plus cher car ça a été trop vite à l'ouverture.  Je reste sur TDG, stop remonté à 46, on a une double insidebar.  Je propose pour ce soir PDLI, on a une divergence haussière sur le stochastic et une possible sur le MACD.  Je viserai M20.